SOMPRODUCT: meer dan SOM en PRODUCT

SomProductSOMPRODUCT: één van de vele functies van Excel. Waar kan die voor gebruikt worden?
In dit artikel zal ik laten zien dat het meer kan zijn dan een optelling van getallen nadat die vermenigvuldigd zijn, zoals de formule hiernaast weergeeft.
Nog sterker: ik denk dat in de praktijk het (meer oneigenlijke) gebruik van de functie vaker wordt toegepast dan zoals de functie oorspronkelijk bedoeld was.

Standaard-gebruik van SOMPRODUCT

SomProduct1Laten we als simpel voorbeeld een bedrijfje nemen met 4 producten met verschillende prijzen. SomProduct2Tijdens de verkoop in de winkel wordt het aantal verkochte producten netjes bijgehouden. Op het einde van de dag willen we natuurlijk wel snel weten wat de omzet is geweest.
In het Voorbeeldbestand in het tabblad Vb1 heb ik de fictieve verkoopaantallen opgenomen. Om de omzet te bepalen moeten we de aantallen nog vermenigvuldigen met de bijbehorende prijs en alle bedragen optellen.
De standaardmethode is dan als volgt:

  1. Voeg een kolom toe waar de prijs van het product komt te staan. Dit kan makkelijk met een zoek-formule in cel G4 (in het voorbeeld staan Product en Aantal in de kolommen E en F):
    =VERT.ZOEKEN(E4;B$4:$C$7;2;ONWAAR)
    Kopieer deze formule naar beneden.
  2. De omzet komt in kolom H: in iedere regel wordt de cel in kolom F vermenigvuldigd met de cel in G.
  3. Dan onderaan in H27 een SOM-formule en we zijn klaar.

Met de Excel-functie SOMPRODUCT kunnen we de stappen 2 en 3 vervangen door één formule (in cel H28):
=SOMPRODUCT(F4:F26;G4:G26)

Wat doet deze formule: de inhoud van cel F4 wordt vermenigvuldigd met die in cel G4, F5 met G5 enzovoort tot en met de vermenigvuldiging van F26 en G26; de resultaten van de vermenigvuldigingen (PRODUCT) worden opgeteld (SOM).

NB bij het ‘nette’ gebruik van SOMPRODUCT worden de arrays gescheiden door een ; (punt-komma). Het is echter ook toegestaan om de matrices met elkaar te vermenigvuldigen. De formule wordt dan:
=SOMPRODUCT(F4:F26*G4:G26) (zie cel H29)
We zullen hieronder zien, dat deze vorm allerlei mogelijkheden biedt voor filtering van resultaten.
Een ander voordeel is, dat de formule geëvalueerd kan worden:

  1. SomProduct3selecteer cel H29
  2. kies in de menutab Formules in het blok Formules controleren de optie Formule evalueren
  3. er verschijnt een nieuw scherm:
    SomProduct4Klik op Evalueren en Excel zal de onderstreepte bewerking gaan uitvoeren (in dit geval de vermenigvuldiging van de 2 arrays).
    Je ziet dan de tussenresultaten (zoals we zelf ook hadden berekend in de cellen H4 t/m H26) omgeven door accolades ten teken dat het resultaat ook weer een array/matrix is. Bij de volgende evaluatiestap worden de tussenresultaten opgeteld.

SomProduct5Met wat creativiteit kan de standaard-formule ook nog anders gebruikt worden.
Stel dat we in de winkel niet de aantallen, maar de omzet bijhouden en we willen weten hoeveel stuks er over de toonbank zijn gegaan, dan doen we iets vergelijkbaars als hiervoor: een kolom met de prijs toevoegen en daarachter geen vermenigvuldiging maar een deling (omzet/prijs) en dan die aantallen onderaan optellen (zie Voorbeeldbestand in het tabblad Vb1).
Ook dit kan sneller met SOMPRODUCT:
=SOMPRODUCT(K4:K26;1/(L4:L26))

Verbaasd? Weet je nog bij wiskunde: delen door een getal is hetzelfde als vermenigvuldigen met het omgekeerde.
Dus we vermenigvuldigen de omzet (kolom K) met het omgekeerde van de prijs (dus 1 gedeeld door kolom L).

SOMPRODUCT voor gevorderden 1

Maar nu begint het pas leuk te worden!
Nu we ongeveer weten hoe SOMPRODUCT werkt, gaan we nog eens wat andere arrays toevoegen.

In het Voorbeeldbestand heb ik op tabblad Vb2 hetzelfde verkoopoverzicht staan. SomProduct6Waar we hiervoor een totale omzet hebben berekend, gaan we nu de omzet per product uitrekenen zonder  gebruik van een hulpkolom.

De formule: =SOMPRODUCT(($E$4:$E$26=I4)*($F$4:$F$26)*($G$4:$G$26)) in cel J4 volstaat om het resultaat 1.590 te berekenen.
De laatste 2 matrices kennen we al van de totalen-berekening (nu absoluut gemaakt zodat de formule naar beneden naar de andere drie producten kan worden gekopieerd).
Met de eerste array is iets ‘geks’ aan de hand: we gebruiken niet de inhoud zelf van de cellen E4 t/m E26 maar het resultaat van een vergelijking met cel I4: als de inhoud van cel E4 gelijk is aan de inhoud van cel I4 dan wordt het resultaat WAAR anders ONWAAR.
Voor Excel is WAAR gelijk aan 1 en ONWAAR gelijk aan 0; dus bij vermenigvuldigen wordt alleen de omzet meegeteld als de vergelijking met I4 WAAR is.

Bekijk met Formule evalueren de tussenstappen:  SomProduct7  SomProduct8  SomProduct9  ……
SomProduct10 etc

SOMPRODUCT voor gevorderden 2

Maar we hoeven het natuurlijk niet bij één filter/selectie te houden.
SomProduct11In het Voorbeeldbestand op het tabblad Vb3 staat een iets uitgebreider omzetoverzicht. Aangezien we nu ook  informatie over de regio hebben kunnen we daar ook op selecteren/filteren bij het berekenen van de totale omzet:
in cel H4 komt dan =SOMPRODUCT(($B$3:$B$1002=$H$2)*($C$3:$C$1002=$H$3)*$E$3:$E$1002)

Op dezelfde manier turven we ook het aantal keren, dat er voor de regio Noord het product Een is verkocht: =SOMPRODUCT(($B$3:$B$1002=$H$2)*($C$3:$C$1002=$H$3))

Tik in cel H2 Zuid in en de resultaten staan in de cellen H4 en H5!

Voor Draaitabel-adepten (net als ik!) is dit allemaal spielerei en moeilijk gedoe: met 8 muisklikken (en nog een paar extra om de opmaak te regelen) heb je al een totaaloverzicht met alle gewenste uitsplitsingen (zie tabblad Vb3).
Maar ik moet toegeven dat de mogelijkheden van SOMPRODUCT soms verder gaan: je kunt de formules op iedere willekeurige plaats gebruiken en bent dus niet gebonden aan het draaitabel-stramien.
En ook de filteringsmogelijkheden gaan verder:

SomProduct12In het omzetoverzicht is een verkoopdatum opgenomen; door een juiste filtering bepalen we de totalen per maand (ik weet het: met groeperen kan dat ook simpel in een draaitabel!). De formule voor het aantal wordt dan:
=SOMPRODUCT(1*(MAAND($D$3:$D$1002)=$H$7))

LET OP omdat we maar 1 selectie/filtering hebben, hebben we dus ook maar 1 array met daarin de waardes WAAR en ONWAAR. Bij de vorige voorbeelden werden die door Excel naar 1 en 0 vertaald bij de vermenigvuldiging. In dit geval forceren we een berekening door de waarden van de array met 1 te vermenigvuldigen. Een andere berekening is 0 erbij optellen (zie cel I9) of om het tegenovergestelde ervan te pakken (min-teken ervoor zetten; is hetzelfde als vermenigvuldigen met -1; zie cel J9). Doe dat laatste 2x om het juiste teken te krijgen!
Bekijk de tussenstappen met Formule evalueren.

In het tabblad Vb3 zijn nog andere voorbeelden opgenomen, die met een draaitabel niet of moeizaam kunnen worden opgelost. Via de juiste formules is het ook mogelijk om op stukken tekst te filteren.  In cel H12 staat:
=SOMPRODUCT(ISGETAL(VIND.ALLES(H11;$B$3:$B$1002))*$E$3:$E$1002)

Als de tekst uit H11 voorkomt in de cellen in kolom B (VIND.ALLES levert dan een getal op, namelijk de positie waar de tekst gevonden is) dan levert ISGETAL de waarde WAAR op, anders ONWAAR. Bij de vermenigvuldiging met de waardes uit kolom E worden deze automatisch vertaald in 1 en 0. Ook hier: bekijk de tussenstappen met Formule evalueren.

LET OP de functie VIND.ALLES is hoofdletter-gevoelig.

SOM voor gevorderden

Voor de liefhebbers: de eigenschap van SOMPRODUCT, dat berekeningen worden uitgevoerd op reeksen/arrays/matrices kunnen we ook toepassen bij veel ‘gewone’ Excel-functies, zoals SOM.

In I16 wordt SOM gebruikt ipv SOMPRODUCT. Maar om Excel te laten weten, dat er een matrix-berekening moet worden uitgevoerd moet je na het invoeren van de formule NIET op Enter drukken, maar op Ctrl-Shift-Enter (soms afgekort als CSE-invoer).
Excel plaatst dan automatisch accolades rond de formule.

LET OP alleen CSE-invoer kan gebruikt worden voor matrix-berekeningen; zelf plaatsen van accolades werkt niet!

SOMPRODUCT voor zeer gevorderden

Ik kwam deze week toevallig een voorbeeld tegen van SOMPRODUCT waarbij ik toch even op mijn hoofd moest krabben.
Ik heb de formule aangepast voor de Nederlandse versie van Excel en nog wat opmaak toegevoegd:

=”06 “&TEKST(SOMPRODUCT(10^(8-RIJ(INDIRECT(“1:8″)))*ZOEKEN(CODE(HOOFDLETTERS(DEEL(LINKS(SPATIES.WISSEN(SUBSTITUEREN(C3;” “;””))&HERHALING(“0”;8);8);RIJ(INDIRECT(“1:8″));1)));{48;49;50;51;52;53;54;55;56;57;64;68;71;74;77;80;84;87};{0;1;2;3;4;5;6;7;8;9;2;3;4;5;6;7;8;9}));”000 000 00”)

Deze formule zet een telefoonnummer in letters (in reclames werd je er ooit mee dood gegooid; nu zie ik ze niet meer) om naar een echt telefoonnummer:
dus 06 DIZ PK ROI wordt 06 349 757 64.

Gebruik Formule evalueren om de formule te doorgronden op het tabblad Vb4 van het Voorbeeldbestand.

Kom je er niet uit: neem contact op met G-Info.


11 gedachten over “SOMPRODUCT: meer dan SOM en PRODUCT

  1. ik heb een somproduct formule waarmee ik data uit een ander bestand ophaal (die reeds middels autofilter gefilterd is). de formule werkt maar ik wil snappen wat er gebeurt zodat ik hem ook uit kan breiden. ‘Formule evalueren’ brengt mij niet verder daar ik geen bruikbare info te zien krijg, enkel een lange rij 0-en.

    dit is de formule:
    =SOMPRODUCT(SUBTOTAAL(3;VERSCHUIVING(‘[test bestand input.xlsx]Vluchten richting Nederland’!$G:$G;RIJ(‘[test bestand input.xlsx]Vluchten richting Nederland’!$G:$G)-MIN(RIJ(‘[test bestand input.xlsx]Vluchten richting Nederland’!$G:$G));;1)); –( LINKS(‘[test bestand input.xlsx]Vluchten richting Nederland’!$G:$G;8)=LINKS(A4;8)))

    Wat ik mij afvraag: wat is de functie van de ‘ — ‘ aan het einde van formule (die in dit geval voor een filter zorgt qua data die opgehaald wordt.

    2e vraag: ik heb in cel B2 en C2 2 waarden staan die de opgehaalde data verder moeten specificeren. ik wil dat toevoegen aan de gegeven formule, maar snap/zie niet waar/hoe ik dat nu moet doen.

    simpel nog een –( ‘[test bestand input.xlsx]Vluchten richting Nederland’!$G:$G=B2)
    toevoegen aan de formule werkt niet heb ik al ontdekt.

    Ben benieuwd of er wat ligt in te schijnen is.

  2. Beste Gijs,
    Ik heb de volgende vraag over de somproduct formule in onderstaand overzicht;

    Ik heb een lange lijst waarin allerlei variaties in kolom A;B;C;D en F zijn. Kolom F is verder overigens niet van belang. Voor mij is van belang uit te kunnen rekenen wat het aantal in kolom B is bij gelijkblijvende gegevens in kolom A;C en D.
    Hieronder een paar regels als voorbeeld.

    Het antwoord zou moeten zijn bij elke van deze regels “2”. Maar de formule geeft mij het antwoord “5”.
    =SOMPRODUCT(($A:$A=A8)*($C:$C=C8)*($D:$D=D8))

    vak programma periode docent aantal onderw.progr. groep
    PL3GD A p4 ZIJT 5 02-1a ma
    PL3GD A p4 ZIJT 5 02-1d
    PL3GD B p4 ZIJT 5 02–12B di
    PL3GD B p4 ZIJT 5 02–1b ma
    PL3GD A p4 ZIJT 5 02-1c

    Wat doe ik fout?
    Hoop dat je me kunt helpen.
    Groetjes
    Marleen Lycops

    1. Dag Marleen,
      met jouw formule turf je hoe vaak een combinatie uit kolommen A, C en D voorkomt (in het voorbeeld zijn die allemaal gelijk, dus 5 keer).
      Ik neem aan dat je bv wilt weten hoe vaak A uit kolom B voorkomt met dezelfde gegevens uit A, C en D.
      Dan moet je de formule uitbreiden: =SOMPRODUCT(($A:$A=A8)*($C:$C=C8)*($D:$D=D8)*($B:$B=B8))
      Succes!

      Mvg
      Gijs Verbruggen

  3. Hoi Gijs, ik worstel al even met het volgende, wellicht kun jij me helpen? Ik zoek naar 3 specifieke stukken tekst in 1 cel, waarbij de uitkomst een simpele J of N moet zijn. De tekst staat verspreid over de cel, en niet netjes achter elkaar helaas. Ik heb hiervoor de volgende formule, maar deze geeft ook een J als er slechts 1 deel van de tekst gevonden wordt, en dat is uiteraard niet de bedoeling.

    Formule: =ALS(SOMPRODUCT(- – ISGETAL(VIND.SPEC({“waar”;”hoe”;”wie”};A2)))>0;”J”;”N”)

    Ik hoop dat je me kunt helpen!

    Groet, Jelte

    1. In jouw formule >0 vervangen door =3.
      De volgende formule zal voor jou ook werken:
      =ALS(SOM(- -ISGETAL(VIND.SPEC(“waar”;B3))- -ISGETAL(VIND.SPEC(“hoe”;B3))- -ISGETAL(VIND.SPEC(“wie”;B3)))=3;”J”;”N”)

      Dus ieder woord afzonderlijk testen en het resultaat (0 of 1) optellen.
      Zo zou je ook kunnen testen of er 2 van de 3 woorden in voorkomen (door de =3 te veranderen in =2).

      Mvg
      Gijs Verbruggen

  4. Dag Gijs,

    Ik heb ‘m nog niet opgelost die langste formule in somproduct maar zag al wel dat de spaties.wissen overbodig wordt als je elke spatie substitueert door een “”.

    Somproduct is een geweldige formule, vandaar dat ik je voorbeelden in dank en met plezier analyseer en gebruik waar ik kan.

    Gelijk aan H29 van tab Vb1 kan dan in M29 van tab vb1 SOMPRODUCT(K4:K26/L4:L26) geplaatst worden, als een duidelijker leesbare versie van =SOMPRODUCT(K4:K26;1/(L4:L26)). Het blijkt dat +plus, -min en /delen ook zijn toegestaan.
    Zeer bruikbaar als je onder dezelfde condities meerdere kolommen wilt gebruiken.

    Ik zoek naar een mogelijkheid om een OF of EN in een conditie te gebruiken (in plaats van twee somproduct formules op te tellen).

    Gelijk maak ik gebruik van de gelegenheid je te complimenteren met je website met uitleg en voorbeelden. Heel plezierig om te gebruiken en erg leerzaam.

    1. Dag Ton,
      bedankt voor je zinvolle aanvullingen en de complimenten!

      De OF-conditie is lastig (niet mogelijk?) met SOMPRODUCT. Zoals je aangeeft kun je 2 formules optellen; dan moet je wel uitkijken dat je geen dubbeltelling krijgt.

  5. Dag Gijs,

    Dank voor je duidelijke uitleg en voorbeelden.
    Je wijst terecht op de mogelijkheden van draaitabellen.
    Misschien zou je hier ook moeten wijzen op … de DB-functies?

    Mvg, Frans

Geef een reactie

Het e-mailadres wordt niet gepubliceerd. Vereiste velden zijn gemarkeerd met *